EXCEL小技巧 | 依據指定次數，將增加空白列、重複資料

如何運用函數來讓資料產生空白列，而且當輸入多少數字，就會插入多少空白列。

【📁檔案下載】

看教學之前可以先下載練習檔，學中做、做中學效果更好哦。

檔案下載

【▶️影音教學】

【📝圖文教學】

<插入空白列>

E5=TOCOL(EXPAND(B5:B9,,C3+1,""))

📝函數說明

✍🏾EXPAND陣列擴展函數
函數說明=EXPAND(範圍,展開的列,展開的欄,要展開的內容)

E5=EXPAND(B5:B9,,C3+1,"")

將B5:B9擴展至C3+1欄(1+1=2)，空白的欄填入""(空格)

✍🏾TOCOL多欄陣列範圍轉一欄
函數說明=TOCOL(範圍,忽略選項,掃描方式)

E5=TOCOL(EXPAND(B5:B9,,C3+1,""))

將原資料與擴展後的空白欄，轉成一欄

<重複資料1>

E5=TEXTSPLIT(CONCAT(REPT(B5:B9&";",C3+1)),,";")

📝函數說明

✍🏾REPT資料重複指定次數
函數說明=REPT(內容,重複次數)

E5=REPT(B5:B9&";",C3)

將B5:B9的內容後面全部加上一個;(分號)，然後指定重複C2儲存格的次數

✍🏾CONCAT合併指定範圍的內容
函數說明=CONACT(內容or參照)

E5=CONCAT(REPT(B5:B9&";",C3))

將所有用REPT重複的內容合併到一個儲存格

✍🏾TEXTSPILT資料剖析函數
函數說明=TEXTSPILT(內容,欄分隔,列分隔,空格,大小寫,無資料時)

E5=TEXTSPLIT(CONCAT(REPT(B5:B9&";",C3)),,";")

利用TEXTSPLIT函數，將;(分號)當作分隔符號，以列的方式展開到每個儲存格

<重複資料2>

E5=TOCOL(TEXTSPLIT(TEXTJOIN(";",,REPT(B5:B9&" ",C3))," ",";"),1,1)

📝函數說明

✍🏾REPT資料重複指定次數
函數說明=REPT(內容,重複次數)

E5=REPT(B5:B9&" ",C3)

將B5:B9的內容後面全部加上一個空格，然後指定重複C2儲存格的次數

✍🏾TEXTJOIN合併文字並在文字間加入指定符號
函數說明=TEXTJOIN(分隔符號,是否忽略空白,文字1,文字2….)

E5=TEXTJOIN(";",,REPT(B5:B9&" ",C3))

把REPT的所有結果用;(分號)當分隔符號，合併到同一個儲存格

✍🏾TEXTSPILT資料剖析函數
函數說明=TEXTSPILT(內容,欄分隔,列分隔,空格,大小寫,無資料時)

E5=TEXTSPLIT(TEXTJOIN(";",,REPT(B5:B9&" ",C3))," ",";")

依據分隔符號(空格)將資料拆分到欄，依據分隔符號(;分號)將資料拆分到列，得到二維陣列。

✍🏾TOCOL多欄陣列範圍轉一欄
函數說明=TOCOL(範圍,忽略選項,掃描方式)

E5=TOCOL(TEXTSPLIT(TEXTJOIN(";",,REPT(B5:B9&" ",C3))," ",";"),3,1)

利用TOCOL把TEXTSPILT得到的二維陣列轉換成一欄，並且忽略空白(引數2輸入3)

，依據列的方式進行掃描(引數3輸入1)

分享如果對你有幫助
歡迎訂閱贊助效率職人沙龍
解鎖更多文章

<訂閱沙龍BONUS>

• 贊助訂閱:🔖99元/月 (3.3/天) | 🔖999/年(2.73/天)
• 限閱文章:4篇文章/月
• 解鎖房間:職場設計新思維
• 解鎖可閱讀內容:

1️⃣ EXCEL特殊圖表
2️⃣ POWER QUERY從0到1
3️⃣ 素材分享(ICON、簡報元素)
4️⃣ 全自動抽獎系統模
5️⃣ 直播分享錄影檔:❌不用函數的日期處理術

• 👍喜歡的話可以幫忙案個讚、分享來幫助更多人或是右下珍藏起來哦
• 💭留言回復「職場生存讚」讓我知道你把這個小技巧學起來了
• ❤️追蹤我的方格子，學習更多職場小技巧
• ☕請我喝杯咖啡，鼓勵我更有動力分享更多優質內容
• 📈訂閱EXCEL設計新思維，學習更多更深更廣的職場技能

😎可以找到我的地方

1. LINE社群
2. IG
3. FB粉絲團
4. YOUTUBE
5. TIKTOK
6. DCARD

raw-image