檔案操作處理工具

linct

發佈於科技的房間

2024/06/07閱讀時間約 54 分鐘

1.工具功能

(1) 可以彈性任意查詢檔案，如對來源目錄設定，對檔案修改日期設定，對檔名特定字串或副檔名設定後，自動查出明細，並可展開至各階子目錄，所有子目錄內的檔案均可操作處理

(2) 依查詢後結果，可產出file name LIST ，提供查詢結果之確認，再依此內容對檔案作複製，移動，刪除，改名等執行操作

(3) 可對檔案作移動，複製至別處，刪除處理，使電腦可騰出硬碟空間

(4) 可執行檔名更改，適用日文，中文檔名顯示。檔案分類歸檔，備份保存管理

(5) 查詢對象檔案之容量可列出，並合計所有查詢對象檔案之檔案數量與file size總容量

2. 作業說明

2.1 於Windows cmd 上執行Manipulate_file.cmd程式時，

出現如下畫面

**** Variable of files manipulate **********

[1] : Inquiry

[2] : Copy ( [1] to be run previously )

[3] : Move ( " )

[4] : Delete ( " )

[5] : Rename ( " )

[9] : Exit

********************************************

使用者依需要輸入欲操作之項目，如下:

1 查詢，2 COPY ，3 MOVE ，4 DEL，5 rename ，9跳出

2.2輸入欲處理檔案之參數，如下四個參數說明:

**1輸入欲查詢來源檔案之Path (path必須存在)

>Source path : like D:\DCS

**2 輸入欲查詢檔案日期期間:

> Date or days : like -30 ，即30天前的選取，

> Date or days : +2023/12/31 ，該當日期以後的檔案選取

沒輸入時default=0

**3 輸入欲查詢檔案名稱之特定字串的，(目錄名稱無法選取)

>String of files : like IT*.txt or *高雄*

沒輸入時default=*.*

**4 查詢後，產出WORKFile ，內含欲查詢之所有檔名，以及若有複製/移動處理時，所需之目的地資料夾名稱

>Destination path: like D:\BK

沒輸入時 default=D:\DESTINATION

2.3 依據 2.2 輸入之參數，找出的檔案集，將查出之對象檔名list儲存在 work Txt檔內

2.3.1 輸入參數後，執行顯示訊息如下:

Next, Enter Parameters in above for inquiring file-name

**1 Enter Source path you want to inquire =I:\99.暫存資料

**2 Enter +-Date or +-days to find file-date =-60

**3 Enter String of file-name you want to inquire =*2NJ*

**4 Enter Destination path for Inquiry/COPY/MOVE files =

**---You entered below parameters want to inquiry---2024/06/06 週四---

**1 Source path :I:\99.暫存資料

**2 Date or days :-60

**3 Sring of files :*2NJ*.*

**4 Destination path:D:\DESTINATION

**---**************************************************************

---Inquiry process 執行中...

---Inquiry process already finished 執行完了, COUNT = 2

---To check you will inquire files-name list in D:\DESTINATION\Inquiry_result.txt

2.3.2 輸入參數，產出work file ，可參考範例如下:

**---You entered below parameters want to inquiry---2021/01/07 週四---

**1 Source path :I:\99.暫存資料

**2 Date or days :-60

**3 Sring of files :*2NJ*.*

**4 Destination path:D:\DESTINATION

2.3.3 上述Work file 內容，找出File 之引數共 7項，以A,B,C,D,E,F,G作為引數名稱，如下

A : Path B:File名 C:副檔名 D:file之修改日期

E: 件數序號 F: file size Byte G: Total file size KB

各引數之間以 ? 做區隔，如下:

I:\99.暫存資料\2NJ 3S kick off .pdf?"2NJ 3S kick off .pdf"?"pdf"?2020/9/15?1

I:\99.暫存資料\2020年式\~$2NJ_SP1 本番.pptx?"~$2NJ_SP1 本番.pptx"?"pptx"?2020/9/25?2

2.3.4 file size 取得, 合計時以 KB單位計算 , if > 512B = 1K ，

注意:合計值不可大於 2147483647 將顯示負值，出現不正確數字

d:\Users\ktmn>set /a v=2147483647

2147483647

d:\Users\ktmn>set /a v=2147483648

不正確的數字。數字限制為 32 位元精確度。

2.4 依據上述出力之WORK file檔內之內容，自動執行複製，移動，刪除，更名等處理

2.4.1 COPY/MOVE 處理:

(1)由Source path PAR1 , 選出所有子目錄，追加新建子目錄至目的地PAR4 下層

PAR1 來源目錄本身，亦需建於PAR4 目的目錄下之子目錄

(2)由Inquiry_result.txt 取出file list,以便 copy/Move 的處理

2.4.2 Delete 處理:

(1)由Inquiry_result.txt 取出file list,以便 Delete 的處理

(2)注意只有刪除檔案，目錄仍會留下不會刪除

2.4.3 Rename 處理:

(1)輸入新檔名，先加上 " "　特別處理,將錯誤字元 " 改為 ###

(2)輸入的新檔名，存檔為temp_rename.txt，

再判斷是否含 "\ > ? < * / : | ###" 任何一錯誤字元，若有需重新輸入

(3)判斷是否要含舊檔名

(4) 依據Inquiry_result.txt內容，取出引數共五項，

A : Path B:File名 C:副檔名 D:file之修改日期 E: 件數序號 ,以便更名的處理

保留舊檔名處理：

rename old-file-Path "Newfile-name_count_oldfile-name"

不保留舊檔名處理：

Rename old-file-Path "Newfile-name_count.old-ext"　

2.4.4 查詢參數的輸入處理:

(1)PAR1 來源目錄輸入，最後之字元不可 \

(2)PAR2 來源File 修改日的選取輸入，default +0

(3)PAR3 來源File name 的選取輸入，default *.* ，

若無副檔名，後面追加 .* 目的是不要選取目錄

(4)PAR4 目的目錄輸入，若不存在，需先新建目錄， default D:\DESTINATION

(5)輸入完成之參數，將內容儲存在WORK file >%PAR4%\Inquiry_result.txt

3. 實例說明

3.1 實例1 : 公用槽內 ,檔案之特定日期前，特定副檔名之檔案處理

**** Variable of files manipulate **********

[1] : Inquiry

[2] : Copy ( [1] to be run previously )

[3] : Move ( " )

[4] : Delete ( " )

[9] : Exit

********************************************

Select Variable in above you will manipulate =1

**--- You can refer parameters sample as below: ----------

**1 Source path : like D:\DCS

**2 Date or days : like -30 or -2019/12/31 default=0

**3 String of files : like IT*.txt or *事懇* default=*.*

**4 Destination path: like D:\BK default=D:\DESTINATION

**--------------------------------------------------------

Next, Enter Parameters in above for inquiring file-name

**輸入欲查詢參數，亦即查詢

I:\99.暫存資料\游捷 ->查該路徑下之檔案

+2023/4/1 -> 查2023/4/1 以後出力之檔案

*.xls* ->查所有excel 檔案

**1 Enter Source path you want to inquire =I:\99.暫存資料\游捷

**2 Enter +-Date or +-days to find file-date =+2023/4/1

**3 Enter String of file-name you want to inquire =*.xls*

**4 Enter Destination path for Inquiry/COPY/MOVE files =

**產出輸入查詢參數

**---You entered below parameters want to inquiry---2024/05/27 週一---

**1 Source path :I:\99.暫存資料\游捷

**2 Date or days :+2023/4/1

**3 Sring of files :*.xls*

**4 Destination path:D:\DESTINATION

**---**************************************************************

=---Inquiry process 執行中...

=---Inquiry process already finished 執行完了

=---To check you will inquire files-name list in D:\DESTINATION\Inquiry_result.txt

請按任意鍵繼續 . . .

** 查詢執行後，結果出力如下

**---You entered below parameters want to inquiry---2024/05/27 週一---

**1 Source path :I:\99.暫存資料\游捷

**2 Date or days :+2023/4/1

**3 Sring of files :*.xls*

**4 Destination path:D:\DESTINATION

I:\99.暫存資料\游捷\損益表格_202310.xlsx?2023/11/3

I:\99.暫存資料\游捷\損益表.xls?2024/3/11

I:\99.暫存資料\游捷\損益表格.xls?2023/5/14

I:\99.暫存資料\游捷\損益彙整\損益表.xls?2023/5/11

I:\99.暫存資料\游捷\損益彙整\損益表格_202405.xls?2024/5/14

I:\99.暫存資料\游捷\損益彙整\損益表格_202311.xlsx?2023/11/13

I:\99.暫存資料\游捷\損益彙整\損益分析2020,03.xlsx?2023/5/18

I:\99.暫存資料\游捷\年度計畫\年度計畫\離職率.xls?2023/10/2

I:\99.暫存資料\游捷\年度計畫\年度計畫\PMA佔有率.xls?2023/11/27

I:\99.暫存資料\游捷\年度計畫\年度計畫\KPI 評價分數.xlsx?2023/11/27

** COPY 處理

**** Variable of files manipulate **********

[1] : Inquiry

[2] : Copy ( [1] to be run previously )

[3] : Move ( " )

[4] : Delete ( " )

[9] : Exit

********************************************

Select Variable in above you will manipulate =2

** COPY 處理後，COPY存入目的地

3.2 實例2 : 公用槽內 ,特定日期前，所有MP3 之檔案查詢

**** Variable of files manipulate **********

[1] : Inquiry

[2] : Copy ( [1] to be run previously )

[3] : Move ( " )

[4] : Delete ( " )

[9] : Exit

********************************************

Select Variable in above you will manipulate =1

**--- You can refer parameters sample as below: ----------

**1 Source path : like D:\DCS

**2 Date or days : like -30 or -2019/12/31 default=0

**3 String of files : like IT*.txt or *事懇* default=*.*

**4 Destination path: like D:\BK default=D:\DESTINATION

**--------------------------------------------------------

Next, Enter Parameters in above for inquiring file-name

**1 Enter Source path you want to inquire =I:\99.暫存資料\NHC

**2 Enter +-Date or +-days to find file-date =-365

**3 Enter String of file-name you want to inquire =*.mp3

**4 Enter Destination path for Inquiry/COPY/MOVE files =

**---You entered below parameters want to inquiry---2020/12/28 週一---

**1 Source path :I:\99.暫存資料\NHC

**2 Date or days :-365

**3 Sring of files :*.mp3

**4 Destination path:D:\DESTINATION

**---**************************************************************

---Inquiry process 執行中...

---Inquiry process already finished 執行完了

---To check you will inquire files-name list in D:\DESTINATION\Inquiry_result.txt

請按任意鍵繼續 . . .

** 查詢結果顯示如下:

**---You entered below parameters want to inquiry---2024/05/27 週一---

**1 Source path :I:\99.暫存資料\NHC

**2 Date or days :-365

**3 Sring of files :*.mp3

**4 Destination path:D:\DESTINATION

I:\99.暫存資料\NHC\1105245_001.mp3?2023/2/25

I:\99.暫存資料\NHC\1105245_002.mp3?2023/2/25

I:\99.暫存資料\NHC\1105245_003.mp3?2023/2/25

I:\99.暫存資料\NHC\1105245_004.mp3?2023/2/25

3.3 實例3 : 公用槽 ,特定日期前，檔案更名之處理

更名為於檔名前追加”台灣”加序號，並保留原有檔名

**** Variable of files manipulate **********

[1] : Inquiry

[2] : Copy ( [1] to be run previously )

[3] : Move ( " )

[4] : Delete ( " )

[5] : Rename ( " )

[9] : Exit

********************************************

Select Variable in above you will manipulate =5

**5_1 Enter New Name you want to renmae file =台灣

台灣

**5_2 If you want keeping old name behind New name, please enter Y (default:N) y

=---Rename process 執行中...

=---Rename process already finished 執行完了

請按任意鍵繼續 . . .

** 更名結果顯示如下:

更名前:

I:\99.暫存資料\NHC\1105245_001.mp3

I:\99.暫存資料\NHC\1105245_002.mp3

I:\99.暫存資料\NHC\1105245_003.mp3

I:\99.暫存資料\NHC\1105245_004.mp3

更名後:

I:\99.暫存資料\NHC\台灣_1_1105245_001.mp3

I:\99.暫存資料\NHC\台灣_2_1105245_002.mp3

I:\99.暫存資料\NHC\台灣_3_1105245_003.mp3

I:\99.暫存資料\NHC\台灣_4_1105245_004.mp3

3.4 實例4 :查詢2011/2/28以前之檔案有哪些?

取得各檔案名稱，容量，並計算出對象檔案集之檔案數與總size容量

**1 Enter Source path you want to inquire =I:\03.分享資料

**2 Enter +-Date or +-days to find file-date =-2011/2/28

**3 Enter String of file-name you want to inquire =

**4 Enter Destination path for Inquiry/COPY/MOVE files =

**---You entered below parameters want to inquiry---週三 2021/02/24---

**1 Source path :I:\03.分享資料

**2 Date or days :-2011/2/28

**3 Sring of files :*.*

**4 Destination path:D:\DESTINATION

**---**************************************************************

*---Inquiry process 執行中...

*---Inquiry process already finished 執行完了, COUNT = 11796 , FsizeTOT = 4028055 KB

*---To check you will inquire files-name list in D:\DESTINATION\Inquiry_result.txt

Press any key to continue . . .

查詢結果如下檔案內容 :

**---You entered below parameters want to inquiry---週三 2024/529--

**1 Source path :I:\03.分享資料

**2 Date or days :-2011/2/28

**3 Sring of files :*.*

**4 Destination path:D:\DESTINATION

I:\03.分享資料\ addLangs.bat?"addLangs.bat"?"bat"?2009/2/10?1?26?0 KB

I:\03.分享資料\ OuiConfigVariables.xml?"OuiConfigVariables.xml"?"xml"?2009/6/3?3?3899?5 KB

I:\03.分享資料\ shiphomeinfo.properties?"shiphomeinfo.properties"?"properties"?2010/7/13?4?36?5 KB

I:\03.分享資料\ shiphomeproperties.xml?"shiphomeproperties.xml"?"xml"?2008/7/25?5?296?5 KB

I:\03.分享資料\ instImages\images.properties?"images.properties"?"properties"?2004/7/29?6?982?5 KB

I:\03.分享資料\DataFiles\Expanded\oui\instImages\oneclickbg.gif?"oneclickbg.gif"?"gif"?2004/7/28?7?15305?19 KB

I:\03.分享資料\ install\access_setup.bat?"access_setup.bat"?"bat"?2010/11/10?8?411?19 KB

I:\03.分享資料\ USRPNNT.TBL?"USRPNNT.TBL"?"TBL"?2007/6/6?11791?12312?4025651 KB

I:\03.分享資料\ winver.exe?"winver.exe"?"exe"?2001/2/6?11792?24064?4025674 KB

I:\03.分享資料\Xusrcj.tbl?"Xusrcj.tbl"?"tbl"?2007/6/5?11793?27490?4025700 KB

I:\03.分享資料\ XUSRPN.TBL?"XUSRPN.TBL"?"TBL"?2007/6/5?11794?12312?4025712 KB

I:\03.分享資料\造字對照表.doc?"造字對照表.doc"?"doc"?2007/6/6?11795?1752576?4027423 KB

I:\03.分享資料\造字對照表.pdf?"造字對照表.pdf"?"pdf"?2007/6/6?11796?647373?4028055 KB

** 上述即查詢取得之對象檔之明細含檔案路徑，日期，file容量，最後一筆顯示總檔案數與總size容量

4. 本工具軟體設計: 程式檔名Manipulate_file.cmd


rem ----本檔案需保存為 UTF-8 ,CHCP 65001 為了顯示特殊字元(✪ 日文) -----

CHCP 65001
@echo off
setlocal
set PAR1=?:
set PAR4=?:

:BEGIN
echo.
echo **** Variable of files manipulate ********** 
echo  [1] : Inquiry 
echo  [2] : Copy   ( [1] to be run previously ) 
echo  [3] : Move   (       "                  ) 
echo  [4] : Delete (       "                  ) 
echo  [5] : Rename (       "                  ) 
echo  [9] : Exit 
echo ******************************************** 

set VAR=
set /p VAR="Select Variable in above you will manipulate ="
if /i "%VAR%"=="1" goto Inquiry
if /i "%VAR%"=="2" goto CopyMove 
if /i "%VAR%"=="3" goto CopyMove 
if /i "%VAR%"=="4" goto Delete
if /i "%VAR%"=="5" goto Rename
if /i "%VAR%"=="9" goto END
goto BEGIN

:Inquiry
CALL :Enter_par
type %PAR4%\Inquiry_result.txt
echo **---**************************************************************
:: ---according 4 par to find files ------
echo *---Inquiry process 執行中...
set /a cnt=0
set /a fsT=0 , fsK=0
:: ---引數---  F:Path  G:file  H:ext  I:fdate  J:fsize
For /f "tokens=1-5 delims=?"  %%F in ( 'forfiles /P "%PAR1%" /S /D %PAR2% /M "%PAR3%" /c "cmd /c echo @path?@file?@ext?@fdate?@fsize" ') do (   
    CALL :WRITE_I_result %%F %%G %%H %%I %%J
     ) 

echo *---Inquiry process already  finished 執行完了, COUNT = %cnt% , FsizeTOT = %fsT% KB 
rem 寫出一筆，後續COPY del 會處理這筆 echo **----- This time inquiry result ----- Files Rec. COUNT = %cnt% , File size TOTAL = %fsT% KB>>  %PAR4%\Inquiry_result.txt
echo *---To check you will inquire files-name list in %PAR4%\Inquiry_result.txt 
echo.
pause --- echo Please check you will inquire files-name list 
goto BEGIN
 
:WRITE_I_result
:: -----取得filesize (%5), 先換算單位為KB ( /1024) 以免超出 2147483647 ，若超出，將不正確計算合計，數值變為負值
set /a cnt=cnt + 1 

:: ----- fsize 先 *10 ，處理五進位 ，以便改為 K 單位-----
set /a fsK=%5 *10 / 1024
if %fsK:~-1,1%  GTR 4   set /a fsK=fsK+10
set /a fsT=fsT + (fsK / 10)

echo %1?%2?%3?%4?%cnt%?%5?%fsT% KB>>  %PAR4%\Inquiry_result.txt 
exit /b

:CopyMove 
if "%VAR%"=="2" (
    set Var_CopyMove=COPY
 ) else (
   if  "%VAR%"=="3" (
     set Var_CopyMove=MOVE ) )

if not EXIST %PAR1%  (echo ###ERROR : while copy/move %PAR1% isn't exist &  goto Inquiry )
if not EXIST %PAR4%\Inquiry_result.txt  (echo ###ERROR : while copy/move Inquiry_result.txt not exist & goto Inquiry )  
echo *---Copy/Move process 執行中...    
::----由Source path(PAR1) , 新建子目錄 至 目的地(PAR4 之下層) --- 
:: ---(1) PAR1 本身先建於 PAR4 之下層，  "%PAR4%%PAR1:~2%"
if not EXIST  "%PAR4%%PAR1:~2%"  (md  "%PAR4%%PAR1:~2%" )

:: ---(2) 再建立 PAR1 下之所有子目錄  ， "%PAR4%%PAR1:~3%"
For /f "tokens=1 delims=?" %%D in ( 'forfiles /P "%PAR1%"  /S /c "cmd /c if @isdir== TRUE  echo @path" ') do ( 
    CALL :MD_SubD  %%D )   
  
::---- 由Inquiry_result.txt 取出file list, then  copy/Move 的處理 ----- 
For /f  "skip=5 tokens=1 delims=?"  %%A in ('type "%PAR4%\Inquiry_result.txt" ') do (  
     CALL :CM_Proc  %%A )   
     
echo *---Copy/Move process already  finished 執行完了 
pause   
goto BEGIN

:MD_SubD
set SubD=%1
if not EXIST  "%PAR4%%SubD:~3%  (md  "%PAR4%%SubD:~3% )
exit /b

:CM_Proc
set FilePath=%1 
%Var_CopyMove%  /Y  %1  "%PAR4%%FilePath:~3%  
exit /b

:Delete 
if not EXIST %PAR4%\Inquiry_result.txt  (echo ###ERROR : while delete Inquiry_result.txt not exist & goto Inquiry )  
echo.
echo *---Are you sure to DELETE inquired files list in %PAR4%\Inquiry_result.txt 
echo.
Pause ---are you sure 
echo *---Delete rocess 執行中...
For /f  "skip=5 tokens=1 delims=?"  %%A in ('type "%PAR4%\Inquiry_result.txt" ') do ( del /F /Q  %%A )   
     
echo *---Delete process already finished 執行完了 
pause   
goto BEGIN

:Rename 
if not EXIST %PAR4%\Inquiry_result.txt  (echo ###ERROR : while Rename Inquiry_result.txt not exist & goto Inquiry )  
echo.

:Enter_NewN
set NewN=
set /p NewN="**5_1 Enter New Name you want to renmae file ="
::---輸入新檔名，先加上 "  "　特別處理,錯誤字元 " 改為 ###
set NN="%NewN:"=###%" 

:: ---輸入新檔名， 存檔為temp_rename.txt，再判斷是否含 "\ > ? < * / : | ###" 任何一錯誤字元 
echo %NN%>  %PAR4%\temp_rename.txt
FINDSTR /v  "\ > ? < * / : | ###"    %PAR4%\temp_rename.txt
if %errorlevel% NEQ  0  (echo ###ERROR : you entered new Fine_name is unavailable & goto Enter_NewN ) 
del /F /Q     %PAR4%\temp_rename.txt

::
set Keep_OldN=N
set /p Keep_OldN="**5_2 If you want keeping old name behind New name, please enter Y  (default:N) "
echo *---Rename process 執行中...
:: ---引數---  A:Path  B:file  C:ext   D:fdate  E:count  
:: Refer TO above :WRITE_I_result "echo %1?%2?%3?%4?%cnt%?%5?%fsT%>>  %PAR4%\Inquiry_result.txt"

For /f  "skip=5 tokens=1-5 delims=?"  %%A in ('type "%PAR4%\Inquiry_result.txt" ') do ( 
    CALL  :Ren_Proc   %%A  %%B  %%C %%D %%E
        )        
echo *---Rename process already finished 執行完了 
pause   
goto BEGIN 

:Ren_Proc
:: --- 將引數檔名與副檔名之" "字元去掉　
set O_File=%2   
set O_Ext=%3    
set O_F2=%O_File:"=% 
set O_E2=%O_Ext:"=%
 
if /i %Keep_OldN% == Y  ( rename %1   "%NewN%_%5_%O_F2%"
           ) else  (      rename %1   "%NewN%_%5.%O_E2%" )
exit /b
  
:Enter_par
echo **--- You can refer parameters sample as below: ----------
echo **1 Source path     : like D:\DCS
echo **2 Date or days    : like -30 or -2019/12/31 default=0
echo **3 String of files : like IT*.txt or *事懇*  default=*.*
echo **4 Destination path: like D:\BK   default=D:\DESTINATION
echo **-------------------------------------------------------- 
echo.
echo Next, Enter Parameters in above for inquiring file-name 
echo.
:Enter_par1
set PAR1=?:
set /p PAR1="**1 Enter Source path you want to inquire ="
if %PAR1:~-1% == \      ( echo ###ERROR : Last character \ is not allowed  & goto Enter_par1  
 )  ELSE (
    IF NOT EXIST "%PAR1%" ( echo ###ERROR : %PAR1% path is not exist  &  goto Enter_par1  ))
 
set PAR2=0
set /p PAR2="**2 Enter +-Date or +-days to find file-date ="

set PAR3=*.*
set /p PAR3="**3 Enter String of file-name you want to inquire ="
:: --- CHECK 若無副檔名，後面追加 .*  目的是不要Find 目錄----
set P3=%PAR3:.=%
if %P3%==%PAR3% set PAR3=%PAR3%.*

:Enter_par4
set PAR4=D:\DESTINATION
set /p PAR4="**4 Enter Destination path for Inquiry/COPY/MOVE files ="
:: --- 若不想區分大小寫，則需要新增 /i 開關，使用 if /i “字串1==字串2”
if %PAR4:~-1% == \   (
          echo ###ERROR : %PAR4% the last character \ is not allowed  
          goto Enter_par4   
  )  ELSE ( 
    if /i "%PAR4%"=="%PAR1%"  (
          echo ###ERROR : %PAR4% path is same of Source path  
          goto Enter_par4  ))
:: --- 若 PAR4 只輸入一個字元 ，則 ERROE
set PAR4A=%PAR4%A
if  %PAR4A:~1,1% NEQ :   (
         echo ###ERROR : %PAR4% is not avaliable  &  goto Enter_par4 
  )  ELSE (
     IF NOT EXIST %PAR4:~0,2% (
         echo ###ERROR :%PAR4:~0,2% Directory is not exit  &  goto Enter_par4
  )  ELSE (
     IF NOT EXIST %PAR4%  (  md %PAR4%  )))
echo.             
echo **---You entered below parameters want to inquiry---%DATE%--- > %PAR4%\Inquiry_result.txt
echo **1 Source path     :%PAR1% >> %PAR4%\Inquiry_result.txt
echo **2 Date or days    :%PAR2%        >> %PAR4%\Inquiry_result.txt
echo **3 Sring of files  :%PAR3%        >> %PAR4%\Inquiry_result.txt
echo **4 Destination path:%PAR4% >> %PAR4%\Inquiry_result.txt
exit  /b 

:END
endlocal

------- recorded by linct ------

26會員

71內容數

樂趣體驗紀錄，沙龍房間有歌唱，生活，科技

留言0

查看全部

發表第一個留言支持創作者！

linct的沙龍的其他內容

閱讀時間約 6 分鐘

閱讀時間約 9 分鐘

閱讀時間約 3 分鐘

閱讀時間約 9 分鐘

閱讀時間約 7 分鐘

閱讀時間約 15 分鐘

你可能也想看

創作者要怎麼好好休息 + 避免工作過量？《黑貓創作報#4》午安，最近累不累？這篇不是虛假的關心。而是《黑貓創作報》發行以來可能最重要的一篇。是的，我們這篇講怎麼補充能量，也就是怎麼休息。

黑貓老師

2024-06-29

#創作 #作者 #社群

使用 C# 操作 App.config 檔案中的設定在開發應用程式時，常常需要設定一些參數或選項，以便於後續調整和管理。在 .NET 中，我們可以使用 App.config 檔案來存儲這些設定，並且可以通過 C# 代碼來讀取和寫入這些設定。本文將介紹如何使用 C# 操作 App.config 檔案中的設定。

Pochi

2024-02-02

#Csharp #AppConfig #程式設計

Python 程式札記 : JSON 檔案操作JSON 格式因為其輕巧、易於讀寫的特性，所以普遍應用於數據儲存。本文將介紹如何使用 Python 來讀取、處理、解析和修改 JSON 檔案。

梧笙

2024-01-23

#python #Python #程式

Python 程式札記 : CSV 檔案操作在數據分析的工作中，處理 CSV 檔案是一項基礎且重要的技能，CSV 格式的檔案是以純文字形式儲存表格數據，簡潔的結構使其普遍應用於數據儲存。本文將介紹如何使用Python 來讀取、處理和儲存 CSV 檔案。

梧笙

2024-01-19

#python #Python #程式

[PHP]檔案操作函數路徑處理 basename(string [.string])：回傳第一個參數路徑字串的檔案名稱，包含副檔案，如果有第二個參數字串，就會在檔案名稱刪除此字串，例如：刪除副檔名".php"。 dirname(string)：回傳參數路徑字串中的路徑。 realpath(string)：回傳參數路

小黑

2023-12-05

#basename #dirname #PHP

Node.js 學習筆記(二)：用 JavaScript 操作電腦的檔案系統用 Node.js 實作電腦檔案系統操作，包含建立資料夾、新增檔案等等。

蕭宇廷

2023-11-21

#NodeJS #程式學習 #JavaScript

Swift 操作檔案的VC - UIDocumentPickerViewController一樣先來看官方文件 A view controller that provides access to documents or destinations outside your app’s sandbox. 其實就是讓你去讀取檔案App的東西有兩種模式，Don’t copy the do

Michelle Chen

2023-10-16

#swift #讀書筆記

NodeJS 關於 file systems，FS異步同步檔案寫入及讀取操作NodeJS 學習來到 file systems 操作，在文檔操作上有分為同步跟異步的處理，接下來分階段介紹操作函數

DDDDD

2023-09-22

#NodeJS #工程師筆記 #工程師

如何在 Go 中操作檔案👨‍💻 簡介今天快速介紹一下對檔案的操作所使用的package os，包括檔案和資料夾操作等。檔案和資料夾操作 os package 可以執行各種檔案和資料夾操作，如建立、讀取、寫入、刪除檔案，以及取得資料夾內容等。

wang alan

2023-09-20

#Golang #tutorial #檔案

20230720短線操作，○○+5.27％，整體-1.38％，按兵不動昨日美股續漲，道瓊創今年新高，帶動台股開紅，力道中等，主流群族為觀光、造紙

輕紫琉璃

2023-07-20

#投資理財 #股票

《異度神劍3》➤ 你不知道的按鍵操作 | 自動戰鬥 | 自動裝備 | 調整視角 | 自動跑步《異度神劍3》前言大家好~這裡是AdaLee Gaming 大家知不知道，異度神劍3中，除了有劇情中跳出的教學以外，還有更多沒教的功能呢?學會這些操作整個遊戲體驗大幅上升，這篇會告訴大家我個人覺得好用的幾項，包括刷怪神器-自動戰鬥，還有自動跑步、自動裝備，以及最後調整視角的方法。影片介紹:

玫玫物語

2022-08-01

#自動戰鬥 #自動裝備 #調整視角