Julia 資料視覺化(Julia plots)

• 資料視覺化導論
• 長條圖(Bar Chart)
• 直方圖(Histogram)
• 機率密度圖(Density Plot)
• 盒形圖(Box Plot)
• 散佈圖及散佈圖矩陣(Scatter Matrix)
• 圓餅圖(Pie Chart)
• 分位圖(QQ Plot)
• 堆疊柱狀圖(Stake Plot)
• 時間序列圖(Time Series)
• 熱點圖(Heat Map)

1.資料視覺化導論

然而你有思考過，為什麼需要將這些資料繪製成一個又一個的圖形嗎？

2.長條圖(Bar Chart)

Julia程式碼

using CSV, CategoricalArrays, StatsPlots; pyplot()

# 匯入資料
df = CSV.read(".../data/companyData.csv")
# 前五筆資料
│ Row │ Dividend │ StockPrice │ Type   │ MarketCap │ Year  │
│     │ Float64  │ Float64    │ String │ Float64   │ Int64 │
├─────┼──────────┼────────────┼────────┼───────────┼───────┤
│ 1   │ 3.0      │ 1.5        │ A      │ 0.5       │ 2012  │
│ 2   │ 4.2      │ 2.1        │ A      │ 0.85      │ 2013  │
│ 3   │ 4.9      │ 2.6        │ A      │ 1.5       │ 2014  │
│ 4   │ 5.3      │ 3.2        │ A      │ 1.9       │ 2015  │
│ 5   │ 5.5      │ 4.1        │ A      │ 2.1       │ 2016  │
# 將Year轉成levels，代表著不重複的Type種類
# 並以years儲存
years = levels(df.Year)

# 將資料reshape，從一個array轉成一個5X3的matrix
# 讓列代表年分，欄代表公司
data  = reshape(df.MarketCap, 5, 3)
# 繪製長條圖
# 值得一提的是，長條圖有許多種變化形態
# 根據不同的bar_position的設定，可以是堆疊的、分開的...
p1 = groupedbar(years, data, bar_position=:stack)
p2 = groupedbar(years, data, bar_position=:dodge)
plot(p1, p2, bar_width=0.7, fill=[:blue :red :green], label=["A" "B" "C"],
    ylims=(0,6), xlabel="Year", ylabel="Market Cap (MM)",
    legend=:topleft, size=(800,400))

3.直方圖(Histogram)

Julia程式碼

using Plots, Distributions, Random; pyplot()
Random.seed!(0)

# 預計生成的資料筆數
n = 2000
# 生成2000筆服從標準常態分配的資料
data = rand(Normal(),n)
# 為了繪製直方圖，找出資料的最大值及最小值
l, m = minimum(data), maximum(data)
# 設定每一個bin的大小
# 也就是每一個長條的寬度
delta = 0.3;
# 找出長條與長條之間的分隔點
bins = [(x,x+delta) for x in l:delta:m-delta]
# 如果原先bins(長條與長條之間的分隔點)中數值最大的元素
# 小於最大值的話(這代表我們長條與長條之間的分隔點切得還不夠好)
if last(bins)[2] < m
    # 把原先bins中數值最大的元素和m(最大值)插入bins
    # 也就是說，新增一個分隔點
    push!(bins,(last(bins)[2],m))
end
L = length(bins)
# 定義函數inBin()檢查資料是否落在兩間隔分隔點之間
inBin(x,j) = first(bins[j]) <= x && x < last(bins[j])
# 定義函數回傳bin的關渡
sizeBin(j) = last(bins[j]) - first(bins[j])

# 計算所有資料inBin()為true的數量，並除上資料個數
# 也就是說落在這個bin之內的資料的比例
f(j) = sum([inBin(x,j)  for x in data])/n

# 計算長條圖的高度
h(x) = sum([f(j)/sizeBin(j) * inBin(x,j) for j in 1:L])
xGrid = -4:0.01:4
# 內建長條圖
histogram(data,normed=true, bins=L,
    label="Built-in histogram",
    c=:blue, la=0, alpha=0.6)
    
    
# 手刻長條圖
plot!(xGrid,h.(xGrid), lw=3, c=:red, label="Manual histogram",
    xlabel="x",ylabel="Frequency")
    
    
# 機率密度圖
plot!(xGrid,pdf.(Normal(),xGrid),label="True PDF",
    lw=3, c=:green, xlims=(-4,4), ylims=(0,0.5))

4.機率密布圖(Density Plot)

Julia程式碼

using Random, Distributions, StatsPlots; pyplot()
Random.seed!(0)

# 設定參數
mu1, sigma1 = 10, 5
mu2, sigma2 = 40, 12

# 定義兩個平均數及變異數不同的獨立常態分配
dist1, dist2 = Normal(mu1,sigma1), Normal(mu2,sigma2)
p = 0.3

# 和之前有些許不一樣，不再使用單一分配產出的資料進行繪圖
# 這裡使用dist1和dist2所組建出來的mixture distribution
# 有一部分資料(約30%)來自dist1，其餘則來自dist2
mixRv() = (rand() <= p) ? rand(dist1) : rand(dist2)

# 生成資料
n = 2000
data = [mixRv() for _ in 1:n]

# 繪製機率密布圖
density(data, c=:blue, label="Density via StatsPlots",
        xlims=(-20,80), ylims=(0,0.035))
        
        
# 直方圖
stephist!(data, bins=50, c=:black, norm=true,
    label="Histogram", xlabel="x", ylabel = "Density")

5.盒形圖(Box Plot)

Julia程式碼

using CSV, StatsPlots; pyplot()

# 匯入資料並擷取其中一欄位的資料
data1 = CSV.read(".../data/machine1.csv", header=false)[:,1]
data2 = CSV.read(".../data/machine2.csv", header=false)[:,1]
data3 = CSV.read(".../data/machine3.csv", header=false)[:,1]

# 繪製盒形圖
boxplot([data1,data2,data3], c=[:blue :red :green], label="",
    xticks=([1:1:3;],["1", "2", "3"]), xlabel="Machine type",
    ylabel="Pipe Diameter (mm)")

6.散佈圖及散佈圖矩陣(Scatter Matrix)

散佈圖的限制

散佈圖矩陣

Julia程式碼

using RDatasets, Plots, Measures; pyplot()

# 匯入資料iris
data = dataset("datasets", "iris")
println("Number of rows: ", nrow(data))

# 把變數名稱取出
featureNames = string.(names(data))[1:4]
println("Names of features:\n\t", featureNames)
# 花的種類
speciesNames = unique(data.Species)
# 種類的數量
speciesFreqs = [sn => sum(data.Species .== sn) for sn in speciesNames]
println("Frequency per species:\n\t", speciesFreqs)
# 圖形參數設置
default(msw = 0, ms = 3)
# 定義一個散佈圖矩陣，我們需要使用for迴圈來完成
scatters = [
    scatter(data[:,i], data[:,j], c=[:blue :red :green], group=data.Species,
        xlabel=featureNames[i], ylabel=featureNames[j], legend = i==1 && j==1)
    for i in 1:4, j in 1:4 ]
    
    
    
# 畫出散佈圖，...代表依序將圖畫出
plot(scatters..., size=(1200,800), margin = 4mm)

7.圓餅圖(Pie Chart)

Julia程式碼

using CSV, CategoricalArrays, Plots; pyplot()
df = CSV.read(".../data/companyData.csv")

# 將Type轉成levels，代表著不重複的Type種類
# 並以companies儲存
companies = levels(df.Type)

# 抓取2012年及2016年時的市值(MarketCap)
year2012 = df[df.Year .== 2012, :MarketCap]
year2016 = df[df.Year .== 2016, :MarketCap]

# 將公司及市值畫成圓餅圖
# 藉由兩張圓餅圖可以很清楚的看到在這四年各公司市值占比的變化
p1 = pie(companies, year2012, title="2012 Market Cap \n by company")
p2 = pie(companies, year2016, title="2016 Market Cap \n by company")
plot(p1, p2, size=(800, 400))

8.分位圖(QQ Plot)

Julia程式碼

using Random, Distributions, StatsPlots, Plots, Measures; pyplot()
Random.seed!(0)

# 設定係數
b1, b2 = 0.5 , 2
# 定義兩個分配dist1、dist2，分別是有著不同係數的beta分配
dist1, dist2, = Beta(b1,b1), Beta(b2,b2)

# 生成分配
n = 2000
data1 = rand(dist1,n)
data2 = rand(dist2,n)

# 利用直方圖比較兩分配
stephist(data1, bins=15, label = "beta($b1,$b1)", c = :red, normed = true)
p1 = stephist!(data2, bins=15, label = "beta($b2,$b2)",
        c = :blue, xlabel="x", ylabel="Density",normed = true)
        
        
# 利用QQ plot比較兩分配，
# 而我們知道data1、data2並不是屬於同個分配
# 從QQ plot來看，QQ plot也很忠實地呈現了
# 兩分配不相同的事實
p2 = qqplot(data1, data2, c=:black, ms=1, msw =0,
        xlabel="Quantiles for beta($b1,$b1) sample",
        ylabel="Quantiles for beta($b2,$b2) sample",
        legend=false)
plot(p1, p2, size=(800,400), margin = 5mm)

9.堆疊柱狀圖(Stake Plot)

Julia程式碼

using CSV, CategoricalArrays, Plots; pyplot()
df = CSV.read(".../data/companyData.csv")

# 將資料reshape，從一個array轉成一個5X3的matrix
# 讓列代表年分，欄代表公司
mktCap = reshape(df.MarketCap, 5, 3)
# 將Year轉成levels，代表著不重複的Type種類
# 並以years儲存
years  = levels(df.Year)
# Stack plot
# 從圖中就可以很清楚發現
# 各公司中以B公司的成長最為兇猛
# 而C公司市值的占比在2012年時曾市最高的
# 接著市值一路縮水，到2016年反而變成市值最小的公司了。
# 此外，A公司在C公司衰退的過程中則是維持緩慢成長
areaplot(years, mktCap,
    c=[:blue :red :green], labels=["A" "B" "C"],
    xlims=(minimum(years),maximum(years)), ylims=(0,6.5),
    legend=:topleft, xlabel="Years", ylabel="MarketCap")

10.時間序列圖(Time Series)

Julia程式碼

using DataFrames, CSV, Statistics, Dates, Plots, Measures; pyplot()

data = CSV.read(.../temperatures.csv")
brisbane = data.Brisbane
goldcoast = data.GoldCoast

# 兩地區日均溫之差
diff = brisbane - goldcoast
# 對年、月、日的資料做處理
# 生成新變數date(yyyy-mm-dd)
dates = [Date(
            Year(data.Year[i]),
            Month(data.Month[i]),
            Day(data.Day[i])
        ) for i in 1:nrow(data)]
        
        
        
# 將某兩星期的資料抓出來，分別定義為brisFortnight及goldFortnight
fortnightRange = 250:263
brisFortnight = brisbane[fortnightRange]
goldFortnight = goldcoast[fortnightRange]
# 繪圖基本參數設定
default(xlabel="Time", ylabel="Temperature")
default(label=["Brisbane" "Gold Coast"])
# 繪製兩地區均溫的時間序列圖
p1 = plot(dates, [brisbane goldcoast],
        c=[:blue :red])
        
        
        
# 繪製兩地區均溫在某兩星期內的時間序列圖
p2 = plot(dates[fortnightRange], [brisFortnight goldFortnight],
        c=[:blue :red], m=(:dot, 5, Plots.stroke(1)))
        
        
        
# 繪製兩地區均溫差的時間序列圖
p3 = plot(dates, diff,
        c=:black, ylabel="Temperature Difference",legend=false)
        
        
        
# 繪製兩地區均溫差的直方圖
p4 = histogram(diff, bins=-4:0.5:6,
        ylims=(0,140), legend = false,
        xlabel="Temperature Difference", ylabel="Frequency")
plot(p1,p2,p3,p4, size = (800,500), margin = 5mm)

11.熱點圖(Heat Map)

Julia程式碼

using StatsPlots, Distributions, CSV, DataFrames, Measures; pyplot()
realData = CSV.read(".../temperatures.csv")
default(c=cgrad([:blue, :red]),
    xlabel="Brisbane Temperature",
    ylabel="Gold Coast Temperature")
    
    
# 使用marginalhist()函數繪製熱點圖
# 這個內建函數會一同繪製X軸資料及Y軸資料的直方圖
p1 = marginalhist(realData.Brisbane, realData.GoldCoast, bins=10:0.4:45)

# 生成圖片，面對這樣高密度的點資料，熱點圖可使我們很輕易的識別點資料中的高度密集區域
plot(p1, size = (500,500), margin = 10mm)