如果你的算式有很多重複出現的值：
=IFS(AVERAGE(A2:E2) >= 90, "優秀！",
AVERAGE(A2:E2) >= 80, "很讚！",
AVERAGE(A2:E2) >= 70, "很好！",
AVERAGE(A2:E2) >= 60, "還好！",
AVERAGE(A2:E2) < 60, "加油！"))
AVERAGE(A2:E2) 一直反覆出現，讓算式變得很長，如果要改它的話，可能要手動修改、或是用尋找取代功能才行。這有沒有辦法簡化呢？
LET 函式：=LET(平均, AVERAGE(A2:E2),
IFS(平均 >= 90, "優秀！", 平均 >= 80, "很讚！", 平均 >= 70, "很好！",
平均 >= 60, "還好！", 平均 < 60, "加油！")
)
這麼一來這整條算式看起來就清爽許多了！這就是 Google 試算表在前年（2022）推出的新函式，LET 的主要應用之一。
它可以指定某個值、或是某個算式結果的名稱，可以讓它在目前的算式內起作用。像是上面的算式，LET 先把 AVERAGE(A2:E2) 指定成「平均」這個名稱，然後在 LET 之後的算式繼續參照。這就是 LET 函式的基本原理。
LET 函式的優點
- 提高可讀性：
LET函式可以讓公式更簡潔易讀，因為可以將複雜的算式命名為更易理解的名稱。 - 提高可維護性：
LET函式可以讓公式更易於維護，因為可以將公式拆解成更小的部分，每個部分都有自己的名稱。
我個人在寫長算式的時候，也會適度加入 LET，也會搭配之前介紹過的已命名範圍和已命名函式，讓算式看起來更親民。你可以回來這邊複習：
語法
LET(第一組名稱, 第一組算式或值, [第 N 組名稱], [第 N 組算式或值], 剩下的算式)
- 第一組名稱：第一組算式或值的名稱。這邊不寫雙引號，寫中文也可以。
- 第一組算式或值：要計算的第一組值或算式。
- 第 N 組名稱：選填，第 N 組算式或值的名稱，這邊不寫雙引號，寫中文也可以。
- 第 N 組算式或值：選填，要計算的第 N 組值或算式。
- 公式運算式：要傳回的結果。
第 Ｎ 組名稱跟算式要成雙成對地出現，不可以少其中一個。另外 LET 的效用只限於這個算式一次，沒辦法套用在其他算式上。
關於名稱，也有幾點要注意：
- 不可以寫儲存格參照（比如說 A1、A2）
- 不可以用空白、也不可以用特殊字元。
- 不可以用數字開頭（比如說
2024平均）。
範例
歡迎來這邊複製一份練習用的試算表，一起來練練！
我們就來按照開頭提到的方式，利用 LET 來計算各科目的平均、並依照平均值給予評價。先從 F2 開始算平均，算法很簡單，就是：
=AVERAGE(A2:E2)
然後因為等等這個平均值會重複用上，我們就可以先在 AVERAGE 前面寫 LET，讓 LET 去定義這個值叫做「平均」：
=LET(平均, AVERAGE(A2:E2),
這樣一組名稱跟算式就寫好了。如果你還有其他想要命名的，就繼續往後寫，一樣要記得成雙成對地寫。
那麼如果我們沒有其他的要寫了，我們就開始著手寫 IFS：
=LET(平均, AVERAGE(A2:E2),
IFS(
從這邊開始，我們就可以用「平均」這個定義好的名稱，套用在後面的算式了。像是這樣：
=LET(平均, AVERAGE(A2:E2),
IFS(平均 >= 90, "優秀！", 平均 >= 80, "很讚！", 平均 >= 70, "很好！",
平均 >= 60, "還好！", 平均 < 60, "加油！")
)
按下 Enter，看看結果：
出現「很讚」了！接下來你就可以複製算式，往下貼上即可。
我們就算不用 LET，也的確可以得到一樣的結果，但是用上 LET 的話，這樣的算式就會更好讀，也更好維護了。
這只是個簡單的例子給你參考！你可以回顧看看自己的試算表，有沒有什麼可以透過 LET 函式改善的算式，歡迎你動手親自嘗試看看。
如果你喜歡這次的文章，歡迎你透過這些方法支持我：
想要看更多文章的話，歡迎來到我的 Notion 頁面找找有沒有你需要的資源喔！
我是喜特先生，Mr. Sheet，我們下個教學見！